TITLE:  app5

        Confirmatory LCA with 2 latent class variables
        on 2+2 ASB items 
        
DATA:   FILE IS asb.dat;                                                          
        FORMAT IS 34X 54F2.0;
        
VARIABLE: NAMES ARE property fight shoplift lt50 gt50 force threat injure 
    pot drug soldpot solddrug con auto bldg goods gambling
	dsm1-dsm22 sex black hisp single divorce dropout college onset f1 f2 f3
	age94 cohort dep abuse;
    
    USEVAR ARE lt50 threat injure bldg;                                             
            
    CLASSES = c(4);                                                       
           
    CATEGORICAL ARE lt50 threat injure bldg;                                         

ANALYSIS:  TYPE = MIXTURE;

MODEL:     %OVERALL%                                                            
           %c#1%
           [lt50$1*2] (1);
		   [bldg$1*2] (3);
		   [threat$1*2](5);
		   [injure$1*2](7);
            
            %c#2% 
            [lt50$1*2] (1);
		    [bldg$1*2] (3);
		    [threat$1*0](6);
		    [injure$1*0](8);

            %c#3%
            [lt50$1*0] (2);
		    [bldg$1*0] (4);
		    [threat$1*2](5);
		    [injure$1*2](7);

            %c#4% 
            [lt50$1*0] (2);
		    [bldg$1*0] (4);
		    [threat$1*0](6);
		    [injure$1*0](8);
            
OUTPUT:      TECH8; 

!The following code allows us to get the posterior probabilities 
!for being in a particular latent class give a persons response
!a file containing each individual's original 4 variables will be 
!created and it will also contain columns with the prob for each
!class and also an indicator of the most likely class
!NOTE: at the bottom of the output file under SAVEDATA INFORMATION
!it lists the order of the output that will appear in the newly
!created file.

savedata: file is C:\ put path here with file name;
save = cprobabilities;